(in-package :com.tee-it-up-golf.web)

(defconstant +flowplayer-controls-height+ 28
  "Height in pixels of the flowplayer controls")

(defvar *flowplayer-default-controls-width* 468
  "Default Width in pixels of flowplayer controls.")

(defvar *flowplayer-default-video-height* 300
  "Default height in pixels of the flowplayer video screen")

(defcomponent flowplayer-component (html-block-element-mixin)
  ((auto-play :initarg :auto-play :accessor auto-play-p :initform nil)
   (auto-buffer :initarg :auto-buffer :accessor auto-buffer-p :initform t)
   (loop-clips :initarg :loop-clips :accessor loop-clips-p :initform t)
   (hide-controls :initarg :hide-controls :accessor hide-controls-p :initform nil)
   (video-height :initarg :video-height
		 :accessor video-height
		 :initform *flowplayer-default-video-height*)
   (player-width :initarg :player-width :accessor player-width
 		 :initform *flowplayer-default-controls-width*)
   (skin-config :initarg :skin-config :accessor skin-configuration
		:initform nil
		:documentation "List of (:skin-option . value) pairs
		to be inserted into the player skin
		configuration. Valid options are the parenscriptified
		names in the flowplayer skin documentation. In
		addition if nil is specified for a value it is
		properly converted a javascript false.")
   (playlist :initarg :playlist :accessor playlist :initform nil))
  (:default-initargs :dom-id (ps:ps-gensym "flowplayer")))

(defmethod render ((self flowplayer-component))
  (<:div :id (html-element.dom-id self)
	 (<:p
	  (let ((player-id (ps:ps-gensym "fbp")))
	    (<:object
	     :id player-id
	     :declare "declare"
	     :data (action-href
		    (register-action (:with-call/cc t)
		      (call-as-window 'fallback-playlist :playlist (playlist self))))
	     :style (format nil "height: ~Dpx; width: ~Dpx;"
			    (+ +flowplayer-controls-height+ (video-height self))
			    (player-width self))
	     (player-width self))
	    (<:a :href (format nil "#~A" player-id) (<:as-html "Play")))))
  (<:script :src "/static/js/swfobject.js")
  (let ((player-var (gensym "fo"))
	(player-config-var (gensym "fo"))
	(player-id (ps:ps-gensym "fbp")))
    (<ucw:script
        `(defvar ,player-var
	   (new (*s-w-f-object "/static/flash/FlowPlayer.swf"
			       ,player-id
			       ,(format nil "~D" (player-width self))
			       ,(format nil "~D"
					(+ +flowplayer-controls-height+
					   (video-height self)))
			       "7"
			       "#ffffff"
			       t)))
     `(.add-variable ,player-var
		     "config"
		     ,(js:js* `(create :config-inject t)))
     `(defvar ,player-config-var
	(create
	 :video-height ,(video-height self)
	 :play-list (array ,@(mapcar (lambda (entry)
				       `(create ,@entry))
				     (playlist self)))
	 :full-screen-script-u-r-l "/static/js/fullscreen.js"
	 :auto-play ,(if (auto-play-p self) 'true 'false)
	 :auto-buffering ,(if (auto-buffer-p self) 'true 'false) 
	 :loop ,(if (loop-clips-p self) 'true 'false)
	 :hide-controls ,(if (hide-controls-p self) 'true 'false)
	 ,@(mapcan (lambda (config-entry)
		     (list (car config-entry)
			   (if-bind value (cdr config-entry)
			     value
			     'false)))
		   (skin-configuration self))))
     `(dojo.event.connect window
			  "onload"
			  (lambda ()
			    (let ((fp (.get-element-by-id document ,player-id)))
			      (.set-config fp ,player-config-var))))
     `(.write ,player-var ,(html-element.dom-id self)))))

(defcomponent fallback-playlist (window-component)
  ((playlist :initarg :playlist))
  (:default-initargs :content-type "application/smil"))

(defmethod render ((self fallback-playlist))
  (labels ((generate-smil-from-playlist (playlist)
	     (let ((urls (mapcar (lambda (entry) (getf entry :url)) playlist)))
	       (<smil:smil
		(<smil:head)
		(<smil:body
		 (<smil:seq
		  (mapc (lambda (url) (<smil:video :src url))
			urls)))))))
    (generate-smil-from-playlist (slot-value self 'playlist))))


#|(defentry-point "^(test.ucw)$" (:application (get-golf-application :frontend)
					     :class regexp-dispatcher)
    ()
  (call 'golf-window
	:body (make-instance 'flowplayer-component
			     :video-height 240
			     :player-width 320
			     :playlist '((:url "/audio.ucw?file=/tmp/movie.flv")
					 (:url "/audio.ucw?file=/music/josh/2000-Porcupine%20Tree%20-%20Lightbulb%20Sun/04%20Shesmovedon.mp3" :name "Shesmovedon")
					 (:url "/audio.ucw?file=/music/bittorrent/MDB/My%20Dying%20Bride%20-%202006%20-%20A%20Line%20of%20Deathless%20Kings/01%20-%20To%20Remain%20Tombless.mp3" :name "To Remain Tombless")))))

|#